compass 仮想ペンレコーダー{
	モード プログラム
	表示位置 右下
	サイズ設定 600, 300
}

変数 $device = "XGS-600"		#測定デバイスの名称
変数 $port = "COM1"	  			#RS232Cポート番号
変数 $cmd = "\#0002UHFIG1(CR)"	#送信文字列
変数 $waitWR = 200				#送信 - 受信 の間の待ち時間
変数 $waitA = 1000				#繰り返しＡの待ち時間 (ミリ秒)
変数 $waitB = 10000				#繰り返しＢの待ち時間 (ミリ秒)
変数 $cntA =  3600				#繰り返しＡの回数
変数 $cntB =  8280				#繰り返しＢの回数
変数 $total						#待ち時間の合計を保存する変数
変数 $result					#測定デバイスからの取得値を保存する変数 
変数 $time						#時刻を保存する変数

sub 初期設定{
	Excel起動 "paper.xls"
	Word起動 "RS232C.doc"
	RS232C.初期化 $device
	paper.初期化 $device
}

############ 全自動測定 ############
exe 繰り返し測定{
	#paper.クリア
	■呼び出し 待ち時間計算
	■呼び出し ポートを開く
	■繰り返し 送受信と記録, $waitA, $cntA
	■繰り返し 送受信と記録, $waitB, $cntB
	■呼び出し ポートを閉じる
}

exe データクリア{
	paper.クリア
}

############ サブルーチン ############
sub 待ち時間計算{
	計算 $total = 0.01 * int (100 * ($waitA * $cntA + $waitB * $cntB) * 0.001 / 60)
	記録 $total & "分"
}

sub ポートを開く{
	RS232C.開始 $port
}

sub ポートを閉じる{
	RS232C.終了
}

sub 送受信と記録{
	RS232C.送信 $cmd
	待機 $waitWR
	RS232C.受信 ($result)
	時刻保存 ($time)
	記録 $result
	paper.記録 $time, $result
}

sub 停止時{
	■呼び出し ポートを閉じる
}